ASP文件、文件夹操作

14442011-11-20

'**************************************************
  '函数ID:0005[测试某个文件存在否]
  '函数名:CheckFile
  '作 用:测试某个文件存在否
  '参 数:ckFilename ---- 被测试的文件名(包括路径)
  '返回值:文件存在返回True,否则False
  '**************************************************
  Public Function CheckFile(ByVal ckFilename)
   Dim M_fso
   CheckFile=False
   Set M_fso = CreateObject("Scripting.FileSystemObject")
   If M_fso.FileExists(ckFilename) Then
   CheckFile=True
   End If
   Set M_fso = Nothing
  End Function
  '**************************************************
  '函数ID:0006[删除某个文件]
  '函数名:DelFile
  '作 用:删除某个文件
  '参 数:dFilename ---- 被删除的文件名(包括路径)
  '返回值:文件删除返回True,否则False
  '**************************************************
  Public Function DelFile(ByVal dFilename)
   Dim M_fso
   DelFile=False
   Set M_fso = CreateObject("Scripting.FileSystemObject")
   If M_fso.FileExists(dFilename) Then
   M_fso.DeleteFile(dFilename)
   DelFile=True
   End If
   Set M_fso = Nothing
  End Function
  '**************************************************
  '函数ID:0007[判断目录是否存在]
  '函数名:CheckDir
  '作 用:判断目录是否存在
  '参 数:ckDirname ---- 目录名(包括路径)
  '返回值:目录存在返回True,否则False
  '**************************************************
  Public Function CheckDir(ByVal ckDirname)
   Dim M_fso
   CheckDir=False
   Set M_fso = CreateObject("Scripting.FileSystemObject")
   If (M_fso.FolderExists(ckDirname)) Then
   CheckDir=True
   End If
   Set M_fso = Nothing
  End Function
  '**************************************************
  '函数ID:0008[创建目录]
  '函数名:CreateDir
  '作 用:创建目录
  '参 数:crDirname ---- 目录名(包括路径)
  '返回值:目录创建成功返回True,否则False
  '**************************************************
  Public Function CreateDir(ByVal crDirname)
   Dim M_fso
   CreateDir=False
   Set M_fso = CreateObject("Scripting.FileSystemObject")
   If (M_fso.FolderExists(crDirname)) Then
   CreateDir=False
   Else
   M_fso.CreateFolder(crDirname)
   CreateDir=True
   End If
   Set M_fso = Nothing
  End Function
  '**************************************************
  '函数ID:0009[删除目录]
  '函数名:DelDir
  '作 用:删除目录
  '参 数:DlDirname ---- 目录名(包括路径)
  '返回值:目录删除成功返回True,否则False
  '**************************************************
  Public Function DelDir(ByVal DlDirname)
   Dim M_fso
   DelDir=False
   Set M_fso = CreateObject("Scripting.FileSystemObject")
   If (M_fso.FolderExists(DlDirname)) Then
   M_fso.DeleteFolder(DlDirname)
   DelDir=True
   End If
   Set M_fso = Nothing
  End Function
  '**************************************************
  '函数ID:0010[指定目录的文件列表]
  '函数名:ListFiles
  '作 用:指定目录的文件列表
  '参 数:Dirname ---- 目录名(包括路径)
  '返回值:文件列表字符串,之间用“|”相隔
  '**************************************************
  Public Function ListFiles(ByVal Dirname)
   Dim M_fso,fNS,fLS,Fnames,FnamesN
   Set M_fso = CreateObject("Scripting.FileSystemObject")
   If (M_fso.FolderExists(Dirname)) Then
   Set fNS = M_fso.GetFolder(Dirname)
   Set fLS=fNS.Files
   For Each FnamesN in fLS
   Fnames=Fnames & FnamesN.name
   Fnames=Fnames & "|"
   Next
   ListFiles=Fnames
   End If
   Set M_fso = Nothing
  End Function

通过本文您对西安网站建设有了进一步了解,本公司温馨提醒:找西安做网站公司,请选择手续齐全、业务精、服务好的正规公司。

工商网上亮照

版权所有:西安点墨网络科技有限公司 信息备案编号: 陕ICP备11004160号-1

客户服务电话:15229292610

公司注册地址:西安市雁塔区融鑫路丽湾蓝岛1幢3单元16层31605号

临时办公地址:西安市雁塔区朱雀大街紫郡长安F3

Sitemap 网站地图 手机版

服务热线:15229292610

客服信箱:vip@dianmo.cc

846461336327

版权所有:西安点墨网络科技有限公司 信息备案编号: 陕ICP备11004160号-1